Библиотека paszlib кракозябры в национальных символах

[viterik]

IDE Lazarus v.2.2.4
Подскажи пожалуйста. Библиотека paszlib. Появляются кракозябры в наименованиях в фалах (в архиве ZIP) (кириллица)

Использую код со статьи из https://wiki.freepascal.org/paszlib/ru
Архивирование всего дерева каталогов
Этот пример рекурсивно добавит содержимое 'C: MyFolder' в 'myzipfile.zip

Код: Выделить всё

Uses ...Zipper,FileUtil
var
  AZipper: TZipper;
  TheFileList:TStringList;
begin
  MyDirectory:='C:\MyFolder';
  AZipper := TZipper.Create;
  AZipper.Filename := 'myzipfile.zip';
  TheFileList:=TStringList.Create;
  try
    FindAllFiles(TheFileList, MyDirectory);
    AZipper.Entries.AddFileEntries(TheFileList);
    AZipper.ZipAllFiles;
  finally
    TheFileList.Free;
    AZipper.Free;
  end;
end;

мриомио.png

[iskander]

Подскажи пожалуйста. Библиотека paszlib. Появляются кракозябры в наименованиях в фалах (в архиве ZIP) (кириллица)

Использую код со статьи из https://wiki.freepascal.org/paszlib/ru

А на пример из этой же статьи, только повыше, внимания не обратили?
Он прямо так и озаглавлен: Упаковка файлов с сохранением кодировки имен файлов.
То есть ваш пример должен выглядеть как-то так:

Код: Выделить всё

program zip_dir;
{$mode objfpc}{$H+}
uses
  Classes, SysUtils, FileUtil, Zipper;
var
  AZipper: TZipper;
  TheFileList: TStringList;
  MyDirectory: string;
begin
  MyDirectory := 'C:\MyFolder';
  AZipper := TZipper.Create;
  AZipper.Filename := 'myzipfile.zip';
  TheFileList := TStringList.Create;
  try
    FindAllFiles(TheFileList, MyDirectory);
    AZipper.Entries.AddFileEntries(TheFileList);
    AZipper.UseLanguageEncoding := True;
    AZipper.ZipAllFiles;
  finally
    TheFileList.Free;
    AZipper.Free;
  end;
end.


[viterik]

А на пример из этой же статьи, только повыше, внимания не обратили?
Он прямо так и озаглавлен: Упаковка файлов с сохранением кодировки имен файлов.
То есть ваш пример должен выглядеть как-то так:

Ну большое спасибо тебе! Все работает!!!